# $FreeBSD: src/etc/root/dot.cshrc,v 1.29 2004/04/01 19:28:00 krion Exp $
#
# .cshrc - csh resource script, read at beginning of execution by each shell
#
# see also csh(1), environ(7).
#

alias h		history 25
alias j		jobs -l
alias la	ls -a
alias lf	ls -FA
alias ll	ls -lA
alias rm	rm -i
alias mv	mv -i
alias cp	cp -pi
alias hg	'history | grep'
alias psn	'ps -ax | sort -n'
alias ns	netstat -f inet
alias dfu	df -t ufs
alias emake	'make >& err'
alias wcd	'cd `make -V WRKSRC`'

# A righteous umask
umask 22

set path = (/sbin /bin /usr/sbin /usr/bin /usr/games /usr/local/sbin /usr/local/bin $HOME/bin)

setenv	EDITOR	vi
setenv	PAGER	more
setenv	BLOCKSIZE	K

if ($?prompt) then
	# An interactive shell -- set some stuff up
#	set prompt = "%B%n@`/bin/hostname -s`#%b "
	set prompt = "%B%n@%m:%~#%b "
	set filec
	set history = 100
	set savehist = 100
	set mail = (/var/mail/$USER)
	if ( $?tcsh ) then
		set autolist
		set noclobber
		bindkey "^W" backward-delete-word
		bindkey -k up history-search-backward
		bindkey -k down history-search-forward
		if ( "${TERM}" == "xterm-color" ) then
			set text=`whoami`@`hostname -s`
			set prompt = "%{]0;%n@%m:%~%}%B%n@%m:%~#%b "
		endif
	endif
endif
